* Gamma Chapter
drop _all

set seed0 23988                /* Set seed for genbinomial pgm */
set seed 238947                /* Set seed for reproducibility */
set obs 10000                  /* Number of obs = 10,000       */
gen x1 = invnormal(uniform())  /* Creation of random variates  */
gen x2 = invnormal(uniform())
gen x3 = invnormal(uniform())
gen d  = 50+5*int((_n-1)/1000) /* Creation of 10 different denominators */
tab d                          /* Tabulation of the denominator         */

set seed 0
generate xb = 1 + .5*x1 - .75*x2 + .25*x3  /* Create linear predictor */
genbinomial y, xbeta(xb) de(d)             /* Create simulated dataset */
glm y x1 x2 x3, family(bin d) nolog        /* Model y on x1, x2, and x3 */

glm y x2 x3, family(bin d) nolog	/* Here, we omit the x1 covariate */

gen x23 = x2*x3                                /* create interaction       */
gen xb1 = 1 + .5*x1 - .75*x2 + .25*x3 + .2*x23 /* create linear predictor  */
genbinomial y1, xbeta(xb1) de(d)               /* create simulated dataset */

glm y1 x1 x2 x3 x23, family(bin d) nolog

glm y1 x1 x2 x3, family(bin d) nolog

use heart01, clear
glm death anterior hcabg kk2 kk3 kk4 age2-age4, family(bin) irls scale(dev) eform nolog noheader

egen grp=group(anterior-age4)    /* The covariate pattern is  */
                                 /* assigned a group number   */
drop if grp == .                 /* Discard missing values    */
egen cases = count(grp), by(grp) /* Size of covariate pattern */ 
egen die = total(death), by(grp) /* Deaths in pattern         */
sort grp                         /* Sort by covariate pattern */
qui by grp: keep if _n==1        /* Keep one case per pattern */

glm die anterior hcabg kk2 kk3 kk4 age2-age4, family(bin cases) irls eform nolog

glm die anterior hcabg kk2 kk3 kk4 age2-age4, family(bin cases) irls scale(dev) eform nolog noheader

glm die anterior hcabg kk2 kk3 kk4 age2-age4, family(bin cases) l(loglog) scale(dev) eform irls nolog

display chiprob(1, 3.14)

gen t = _n
tis t
glm die anterior hcabg kk2 kk3 kk4 age2-age4, family(bin cases) l(loglog) irls nwest(anderson 2) nolog

williams die cases anterior hcabg kk2 kk3 kk4 age2-age4, eform nolog